#!/usr/bin/env perl
#
# make-dates
# 2024-03-05
#
# generate HCL files for all dates in a given year

require 5.005 ;
use strict ;
use warnings ;

use Getopt::Std ;
use POSIX qw( strftime ) ;
use Time::Local qw( timegm_posix ) ;

###############################################################################
#
# Return the number of days in a given YYYY-MM

sub days_in_month($$)
{
    my $yr  = shift ;
    my $mo  = shift ;

    my @dim = qw( 0 31 0 31 30 31 30 31 31 30 31 30 31 ) ;

    if ( $dim[$mo] > 0 ) { return $dim[$mo] ; }
    if ( $yr %   4 ) { return 28 ; }
    if ( $yr % 100 ) { return 29 ; }
    if ( $yr % 400 ) { return 28 ; }
    return 29 ;
}

###############################################################################
#
# Generate files for a given month

my @dow = qw( Sun Mon Tue Wed Thu Fri Sat ) ;

sub gen_ym($$)
{
    my $yr      = shift ;
    my $mo      = shift ;

    ########################################
    # Build file headers

    my $title1   = strftime( '%B %Y' , 0 , 0 , 12 , 1 , $mo-1 , $yr-1900 ) ;
    my $title2   = strftime( '%b %Y' , 0 , 0 , 12 , 1 , $mo-1 , $yr-1900 ) ;

    my $text_a = <<EOF ;
font    Lines bold 10
moveto  16 10
text    "$title1"
text    "$title2"
font    Lines bold 8
EOF
    my $text_b = $text_a ;

    ########################################
    # Add dates to each file's text

    my $da  = 1 ;
    my $l   = days_in_month( $yr , $mo ) ;
    while ( $da <= $l )
    {
        my $t   = timegm_posix( 0 , 0 , 12 , $da , $mo-1 , $yr-1900 ) ;
        my @d   = gmtime( $t ) ;
        my $w   = $dow[$d[6]] ;
        my $ymd = sprintf( '%04d-%02d-%02d' , $d[5]+1900 , $d[4]+1 , $d[3] ) ;

        my $line    = "text    \"$ymd $w\"\n" ;

        if ( $da < 16 )
        {
            $text_a .= $line ;
        }
        else
        {
            $text_b .= $line ;
        }

        $da ++ ;
    }

    ########################################
    # Run the 'drawj2d' commands

    my $file_a = sprintf( '%04d-%02da.rmn' , $yr , $mo ) ;
    my $file_b = sprintf( '%04d-%02db.rmn' , $yr , $mo ) ;

    print "Creating $file_a\n" ;

    open( O , "| drawj2d -q -Trmn -o $file_a" )
        or die "ERROR: can't run 'drawj2d -Trmn -o $file_a': $!\n" ;
    print O $text_a ;
    close O ;

    print "Creating $file_b\n" ;

    open( O , "| drawj2d -q -Trmn -o $file_b" )
        or die "ERROR: can't run 'drawj2d -Trmn -o $file_b': $!\n" ;
    print O $text_b ;
    close O ;
}

###############################################################################
###############################################################################
###############################################################################

my $y = ( shift || die "ERROR: no year specified\n" ) ;

for my $m ( 1 .. 12 )
{
    gen_ym( $y , $m ) ;
}